***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 21, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJX8603_P-part  D  G  S
Rg     G    1t    1
EVgs 3 2t  TABLE { V(S, 1t) } 
+((0, 0)
+ (0.5 , 0.5  )
+ (1   , 1    )
+ (1.5 , 1.5  )
+ (2   , 2.00 )
+ (2.5 , 2.5  )
+ (2.75, 2.75 )
+ (3   , 3    )
+ (3.5 , 3.35 )
+ (4   , 3.55 )
+ (4.5 , 3.68 )
+ (5   , 3.78 )
+ (8   , 4.45 )
+ (10  , 5.1  )
+ (20  , 6.0  )
+ (22  , 6.0 ))
EVgst 1 2t value = {3e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
M1      2    1    3    3    DMOS    L=1u   W=1u
.MODEL DMOS PMOS (
+  VTO = -1.60
+   KP = 0.458
+LEVEL =3)
Cgs    1t    3    5.42e-11
Rd      D    4    9.226e-1 tc=8e-3,2e-5
Dds     4    3    DDS
.MODEL     DDS    D(IS=1.044E-11 N=1.185 RS=3.817e-2 eg=0.98 CJO=3.202e-11 M=1.057e-1 VJ=1.598e-1)
Dbody   D    3    DBODY
.MODEL   DBODY    D(IS=1.044E-11 N=1.185 RS=3.817e-2 eg=0.98 BV=66 TBV1=5.190e-4 TT=25n)
Ra      4    2    9.226e-1 
Rs      3    5    1e-4
Ls      5    S    0.001n 
M2     1t    8    6    6   INTER
E2      8    6    4    1t   2
.MODEL   INTER    PMOS(VTO=0  KP=10   LEVEL=1)
Cgdmax  7    4    2.5e-11
Rcgd    7    4    10meg
Dgd     4    6    DGD
Rdgd    4    6    10meg
.MODEL     DGD    D(CJO=1.067e-11 M=3.983e-1 VJ=7.551e-1)
M3      7    9    1t    1t   INTER
E3      9    1t    4    1t   -2
.ENDS
*$
.SUBCKT  PJX8603_N-part  D  G  S
Rg     G    1t    1m
M1      2    1    3    3    DMOS    L=1u   W=1u
.model dmos nmos ( 
+vto = {8.825e-1*((8e-3*(temp-25))+1)}
+kp = {5.855e-1*((3e-2*(temp-25))+1)}
+rb = 9.207e-2
+theta = 0.2  
+tnom = 25
+vmax = 0 
+level = 3)   
Cgs	1t	3	50p
Rd	D	4	17e-2	tc = 0.04,1e-4
Dds	3	4	dds
Gds  D  S  value = {4.5e-4*(temp-25)*limit((v(G, S)-1),0,2)*limit(v(D,S),0,1.2)}
.model dds d( bv = 55  ibv = 0.25e-6  tbv1 = 1.2e-3  m=0.36  cjo=32p  vj=0.8
+is = 1.478e-7
+ n = 2.079	
+rs = 9e-2)
e1	1 3 table { v(1t, S) } 
+ ((0, 0)
+  (1.00, 1.00)
+  (1.80, 1.70)
+  (1.90, 1.87)
+  (2.00, 1.98)
+  (2.50, 2.48)
+  (3.00, 3.00)
+  (4.00, 3.29)
+  (4.50, 3.30)
+  (5.00, 3.45)
+  (6.00, 3.46)
+  (8.00, 3.50)
+  (10.0, 3.70)) 
dbody   3   D    dbody
.model   dbody    d(
+is = 1.478e-7
+ n = 2.079
+rs = 8e-2
+tt = 100n	
+vj = 0.8	
+eg = 1 )
ra      4    2    6e-2  tc = 0.025
rs      3    5    6e-2
ls      5    S   0.0001n
m2     1t    8    6    6   inter
e2      8    6    4    1t   2
.model	inter	nmos( vto = 0  kp = 10  level = 1 ) 
cgdmax  7    4    10p
rcgd    7    4    10meg
dgd     6    4    dgd
rdgd    4    6    10meg
.model     dgd    d( m = 0.3   cjo = 68p   vj = 0.4 )
m3      7    9    1t    1t   inter
e3      9    1t    4    1t   -2
.ends
*$
